【Godot4.x】神経衰弱サンプル

## マウスカーソルが入ってきた.
func _on_mouse_entered() -> void:
	_selected = true
	_blink_timer = PI/2/2 # 90度=1.0

## マウスカーソルが出ていった.
func _on_mouse_exited() -> void:
	_selected = false

## 更新 > ひっくり返す.
## @param is_back_card: 裏のカードかどうか.
## @param rot_rate: 回転の割合 (0.0〜1.0)
func _update_flip(is_back_card:bool, rot_rate:float) -> void:
	# 表・裏のスプライトを非表示.
	_back.visible = false
	_front.visible = false
	
	# 回転するスプライト.
	var spr:Sprite2D = _front
	if is_back_card:
		# 対象は裏のカード.
		spr = _back
	# 表示するスプライトだけ表示する.
	spr.visible = true
	# sinカーブで回転.
	spr.scale.x = 1.0 * sin(PI/2 * rot_rate)	

## 状態.
enum eState {
	BACK, # 裏向き.
	BACK_TO_FRONT1, # 裏から表.
	BACK_TO_FRONT2,
	FRONT, # 表向き.
	FRONT_TO_BACK1, # 表から裏.
	FRONT_TO_BACK2,

	VANISH, # 消滅.
}

## 更新.
func _physics_process(delta: float) -> void:
  ...
  _timer += delta
  var rot_rate = 1.0 # 回転の割合.
  var is_back_card = true # 裏向きかどうか.
  
  match _state:
    eState.BACK:
      # 裏向き.
      is_back_card = true
      rot_rate = 1.0
      # 選択カーソル更新.
      _update_blink_select(delta)
      
    eState.BACK_TO_FRONT1:
      # 裏 -> 表 (前半).
      is_back_card = true
      rot_rate = 1 - (_timer / TIME_ROTATE)
      if _timer >= TIME_ROTATE:
        # 後半へ続く.
        rot_rate = 0
        _timer = 0.0
        _state = eState.BACK_TO_FRONT2
    eState.BACK_TO_FRONT2:
      # 裏 -> 表 (後半).
      is_back_card = false
      rot_rate = _timer / TIME_ROTATE
      if _timer >= TIME_ROTATE:
        # 終了.
        is_back_card = false
        rot_rate = 1.0
        _state = eState.FRONT
      
    eState.FRONT:
      # 表向き.
      is_back_card = false
      rot_rate = 1.0
      
    eState.FRONT_TO_BACK1:
      # 表 -> 裏(前半).
      is_back_card = false
      rot_rate = 1 - (_timer / TIME_ROTATE)
      if _timer >= TIME_ROTATE:
        # 後半へ続く.
        rot_rate = 0
        _timer = 0.0
        _state = eState.FRONT_TO_BACK2
    eState.FRONT_TO_BACK2:
      # 表 -> 裏(後半).
      is_back_card = true
      rot_rate = _timer / TIME_ROTATE
      if _timer >= TIME_ROTATE:
        # 終了.
        is_back_card = true
        rot_rate = 1.0
        _state = eState.BACK
        
    eState.VANISH:
      # 消滅演出.
      var rate = Ease.cube_out(_timer / TIME_VANISH)
      var card_scale = 1 + rate
      _front.scale = Vector2.ONE * card_scale
      _front.modulate.a = 1 - rate
      if _timer >= TIME_VANISH:
        # 消える.
        queue_free()
      # 消滅はカードの更新を行わないのでここでreturnする.
      return
  
  # フラグに対応した回転処理を行う.
  _update_flip(is_back_card, rot_rate)

## 開始.
func _ready() -> void:
	## キャプションを消しておく.
	_label_caption.visible = false
	
	## スライダーの値を設定.
	_slider_kind.value = Common.cnt_card_kind
	
	## カード配置情報を作成.
	_create_card_array()
			
	## 配情報をシャッフルする.
	_array2.shuffle()
	## デバッグ出力.
	_array2.dump()
	
	## カードを生成.
	_array2.foreach(func(i, j, v):
		var pos = _grid_to_screen(i, j) # スクリーン座標.
		var idx = _grid_to_idx(i, j) # インデックス座標.
		var card = CARD_OBJ.instantiate() # カードインスタンス.
		_card_layer.add_child(card) # カードレイヤーに登録する.
		card.setup(pos, idx, v) # カードをセットアップ.
	)
	
	# 表のカード枚数計算用.
	_front_cnts.resize(Card.eId.size())
	_front_cnts.fill(0)

## 表になっているカードの枚数を数える.
func _count_front_cards() -> void:
	# 0クリア.
	_front_cnts.fill(0)
	
	for card in _card_layer.get_children():
		var c = card as Card
		if c.is_front == false:
			continue # 対象カードは表のものだけ.
		# カウントアップ.
		_front_cnts[c.id] += 1

## カード配置情報を作成.
func _create_card_array() -> void:
	var id = Card.eId.NASU
	var idx = 0
	
	# この数で難易度が決まる.
	var id_max = 1 + (Common.cnt_card_kind) # 出現するカードの数.
	
	for j in range(GRID_CNT_H):
		for i in range(GRID_CNT_W):
			_array2.set_v(i, j, id)
			idx += 1
			if idx%2 == 0:
				# 2枚ずつ作る.
				id = (id+1)%id_max
				if id == Card.eId.NONE:
					# 無効なカードになっていたら+1
					id += 1

## 消去チェック.
## @param is_erase 消去も同時に行うかどうか.
func _check_erase(is_erase:bool) -> bool:
	var ret = false # マッチしたカードがあるかどうか.
	
	var match_list = []
	for idx in range(_front_cnts.size()):
		if _front_cnts[idx] == 2:
			# 2枚表向きならそろっているとみなす.
			match_list.append(idx)
	
	for idx in range(_front_cnts.size()):
		if not idx in match_list:
			continue # マッチリストにいない.
		
		# マッチしたカードがある.
		ret = true
		
		# マッチしたカードを消す.
		for card in _front_cards:
			if card.id == idx:
				if is_erase:
					# 消去する.
					card.vanish()
	
	return ret

## 更新 > メイン.
func _update_MAIN(_delta:float) -> void:
	if _front_cards.size() >= 2:
		# カードを2枚めくったのでそろったかどうかの判定を行う
		_state = eState.WAIT1
		_timer = 0
		return
		
	if _card_layer.get_child_count() == 0:
		# 場のカードがなくなったらクリア.
		_state = eState.GAMECLEAR
		return	
	
	# めくり判定.
  ...