【Godot】Navigation2Dを使用した経路探索の実装方法

extends Node2D

# 経路探索2D
onready var nav_2d := $Navigation2D

# 経路を視覚的に表示する線
onready var line_2d := $Line2D

# キャラクター
onready var godot := $Godot

# 左マウスクリックを処理する
func _unhandled_input(event: InputEvent) -> void:
	if not event is InputEventMouseButton:
		return # マウスイベントでない
	if event.button_index != BUTTON_LEFT or not event.pressed:
		return # 左クリックでない
	
	# キャラクターから左クリックした位置までの経路を求める
	var new_path = nav_2d.get_simple_path(godot.position, event.position)
	
	# 経路を線で視覚的に表示する
	line_2d.points = new_path

extends Sprite

# 移動速度
var speed := 400.0

# パス情報
var path := PoolVector2Array() setget set_path

func _ready() -> void:
	# _process()を起動時は無効にする
	set_process(false)

func _process(delta: float) -> void:
	# 移動速度を計算する
	var move_distance := speed * delta

	# パスに沿って移動する
	move_along_path(move_distance)
	
# パスに沿って移動する
# @param distance 移動距離
func move_along_path(distance:float) -> void:
	# 開始座標
	var start_point := position
	for i in range(path.size()):
		# 次の移動ポイント
		var next_point := path[0]
		
		# 開始座標から次の移動先への距離を求める
		var distance_to_next := start_point.distance_to(next_point)
		if distance <= distance_to_next and distance >= 0.0:
			# 移動距離が次への距離距離より小さい、かつ移動距離が残っていれば
			# 次の移動ポイントまで移動する
			position = start_point.linear_interpolate(next_point, distance / distance_to_next)
			# 移動できた
			break
		elif distance < 0.0:
			# 移動完了
			position = next_point
			set_process(false)
			break
		
		# 移動した距離だけ差し引く
		distance -= distance_to_next
		
		# 開始地点を移動させる
		start_point = next_point
		
		# 移動完了したパス(先頭の座標)を消しておく
		path.remove(0)
		
# setter
func set_path(v:PoolVector2Array) -> void:
	path = v
	if v.size() > 0:
		# 移動可能
		# _process()を開始する
		set_process(true)

extends Node2D

# 経路探索2D
onready var nav_2d := $Navigation2D

# 経路を視覚的に表示する線
onready var line_2d := $Line2D

# キャラクター
onready var godot := $Godot

# 左マウスクリックを処理する
func _unhandled_input(event: InputEvent) -> void:
	if not event is InputEventMouseButton:
		return # マウスイベントでない
	if event.button_index != BUTTON_LEFT or not event.pressed:
		return # 左クリックでない
	
	# キャラクターから左クリックした位置までの経路を求める
	var new_path = nav_2d.get_simple_path(godot.position, event.position)
	
	# 経路を線で視覚的に表示する
	line_2d.points = new_path
	
	# キャラクターに移動経路を設定しておく
	godot.path = new_path