【Godot】倉庫番の実装サンプルと解説

## レベルシーンのパスを取得する.
func get_level_scene(level:int=0) -> String:
	if level <= 0:
		# 指定がない場合は現在のレベルを使用する.
		level = _level
	
	return "res://src/level/level%02d.tscn"%level

func _ready() -> void:

	...

	# Frontのタイルマップを取得する.
	var tile_front = level_obj.get_node("./Front")
	
	# フィールドをセットアップする.
	Field.setup(tile_front)

	# Frontタイルの情報からインスタンスを生成する.	
	for j in range(Field.TILE_HEIGHT):
		for i in range(Field.TILE_WIDTH):
			var v = tile_front.get_cell(i, j)
			if _create_obj(i, j, v):
				# 生成したらタイルの情報は消しておく.
				tile_front.set_cell(i, j, Field.eTile.NONE)

## タイル情報から生成されるオブジェクトをチェック＆生成.
func _create_obj(i:int, j:int, id:int) -> bool:
	match id:
		Field.eTile.START:
			# プレイヤー開始位置.
			_create_player(i, j)
			return true
		Field.eTile.CRATE1, Field.eTile.CRATE2, Field.eTile.CRATE3, Field.eTile.CRATE4:
			# 荷物.
			_create_crate(i, j, id)
			return true
	
	# 生成されていない.
	return false

enum eTile {
	NONE = -1,
	# 通路
	BLANK = 0,
	# 壁
	BLOCK = 1,
	# 荷物
	CRATE1 = 2,
	CRATE2 = 3,
	CRATE3 = 4,
	CRATE4 = 5,
	# 荷物を移動させる場所.
	POINT1 = 6,
	POINT2 = 7,
	POINT3 = 8,
	POINT4 = 9,
	# プレイヤー
	START = 10, # 開始地点
}

extends Area2D

# ===========================
# グリッド(インデックス)座標系で動作するオブジェクトの既定.
# ===========================
class_name GridObject

# ---------------------------------------
# preload.
# ---------------------------------------
const Point2 = preload("res://src/common/Point2.gd")

# ---------------------------------------
# vars.
# ---------------------------------------
var _point = Point2.new()
var _dir:int = Direction.eType.DOWN

# ---------------------------------------
# public functions.
# ---------------------------------------
## グリッド座標系を設定.	
func set_pos(i:int, j:int, is_center:bool) -> void:
  # グリッド座標系をワールド座標に変換して描画座標に反映する.
	position.x = Field.idx_to_world_x(i, is_center)
	position.y = Field.idx_to_world_y(j, is_center)

	# グリッド座標を設定.
	_point.set_xy(i, j)

## 方向を設定する.
func set_dir(dir:int) -> void:
	_dir = dir

## 指定の座標と一致しているかどうか.
func is_same_pos(i:int, j:int) -> bool:
	return _point.equal_xy(i, j)

## グリッド座標系のXを取得する.
func idx_x() -> int:
	return _point.x

## グリッド座標系のYを取得する.
func idx_y() -> int:
	return _point.y

extends GridObject
# ===========================
# プレイヤー.
# ===========================

class_name Player
...

extends GridObject
# ===========================
# 荷物オブジェクト.
# ===========================

class_name Crate
...

func proc(delta:float) -> void:
	_anim_timer += delta

	# キーの入力判定.
	var is_moving = false
	if Input.is_action_just_pressed("ui_left"):
		_dir = Direction.eType.LEFT
		is_moving = true
	elif Input.is_action_just_pressed("ui_up"):
		_dir = Direction.eType.UP
		is_moving = true
	elif Input.is_action_just_pressed("ui_right"):
		_dir = Direction.eType.RIGHT
		is_moving = true
	elif Input.is_action_just_pressed("ui_down"):
		_dir = Direction.eType.DOWN		
		is_moving = true
	
	if is_moving:
		# 移動する.
		_move()
		
	_spr.frame = _get_anim_id(int(_anim_timer*4)%4)

## 移動.
func _move() -> void:
	# 移動先を調べる.
	var prev_dir = _dir # 移動前の向き
	var now = Point2.new(_point.x, _point.y) # 現在の位置
	var next = Point2.new(_point.x, _point.y) # 移動先の位置
	# 移動方向.
	var d = Direction.get_point(_dir)
	next.iadd(d) # 加算.
	
	if Field.is_crate(next.x, next.y):
		# 移動先が荷物.
		if Field.can_move_crate(next.x, next.y, d.x, d.y):
			# 移動できる.
			# 荷物を動かす.
			Field.move_crate(next.x, next.y, d.x, d.y)
			# プレイヤーも動かす.
			set_pos(next.x, next.y, true)
		
			# リプレイデータを追加.
			_add_replay(now, prev_dir, next, _dir)

	elif Field.can_move(next.x, next.y):
		# 移動可能.
		set_pos(next.x, next.y, true)
		
		# リプレイデータを追加.
		_add_replay(now, prev_dir, next, Direction.eType.NONE)

extends GridObject
# ===========================
# 荷物オブジェクト.
# ===========================
class_name Crate

# ---------------------------------------
# enum.
# ---------------------------------------
enum eType {
	BROWN = Field.eTile.CRATE1,
	RED = Field.eTile.CRATE2,
	BLUE = Field.eTile.CRATE3,
	GREEN = Field.eTile.CRATE4,
}

# ---------------------------------------
# onready.
# ---------------------------------------
onready var _spr = $Sprite
onready var _spr2 = $Sprite2

# ---------------------------------------
# vars.
# ---------------------------------------
var _type = eType.BROWN
var _timer = 0.0

...

# ---------------------------------------
# public functions.
# ---------------------------------------
## 荷物の種類を取得する.
func get_type() -> int:
	return _type

...

## アニメーションの更新.
func _process(delta: float) -> void:
	_timer += delta
	
	_spr2.visible = false
	if Field.is_match_crate_type(idx_x(), idx_y(), _type):
		# マッチしているので点滅する.
		_spr2.visible = true
		_spr2.modulate.a = 0.5 * abs(sin(_timer*4))

## 指定の荷物が正しい位置にあるかどうか.
func is_match_crate_type(i:int, j:int, type:int) -> bool:
	var v = get_cell(i, j)
	match v:
		eTile.POINT1:
			return type == eTile.CRATE1 # 茶色.
		eTile.POINT2:
			return type == eTile.CRATE2 # 赤色.
		eTile.POINT3:
			return type == eTile.CRATE3 # 青色.
		eTile.POINT4:
			return type == eTile.CRATE4 # 緑色.
		_:
			return false # マッチしてない.

## ステージクリアしたかどうか.
func is_stage_clear() -> bool:
	for crate in Common.get_layer("crate").get_children():
		var i = crate.idx_x()
		var j = crate.idx_y()
		var type = crate.get_type()
		if is_match_crate_type(i, j, type) == false:
			return false # 一致していないものがある.
	
	# すべて一致した.
	return true

## 最終レベルを終えたかどうか.
func completed_all_level() -> bool:
	return _level > FINAL_LEVEL

## リプレイデータ.
class ReplayData:
	var player_pos = Point2.new()
	var player_dir = Direction.eType.NONE
	var crate_pos = Point2.new()
	var crate_dir = Direction.eType.NONE
	func _init(px:int, py:int, dir:int, cx:int=0, cy:int=0, cdir:int=Direction.eType.NONE) -> void:
		player_pos.set_xy(px, py)
		player_dir = dir
		crate_pos.set_xy(cx, cy)
		crate_dir = cdir

	## undoを追加する.
	func add_undo(d:ReplayData, is_clear_redo:bool=true):
		undo_list.append(d)
		if is_clear_redo:
			redo_list.clear() # undoが追加されたらredoは消える.

	## undoを実行する.
	func undo(player:Player):
		if undo_list.empty():
			return # 何もしない.
		
		# 末尾から取り出す.
		var d:ReplayData = undo_list.pop_back()
		player.set_pos(d.player_pos.x, d.player_pos.y, true)
		player.set_dir(d.player_dir)
		if d.crate_dir != Direction.eType.NONE:
			# 荷物の位置も戻す.
			var xprev = d.crate_pos.x
			var yprev = d.crate_pos.y
			var v = Direction.get_point(d.crate_dir)
			var xnow = xprev + v.x
			var ynow = yprev + v.y
			var crate = Field.search_crate(xnow, ynow)
			crate.set_pos(xprev, yprev, true) # 1つ戻す
		
		# redoに追加.
		add_redo(d)

	## redoを実行する.
	func redo(player:Player) -> void:
		if redo_list.empty():
			return # 何もしない.
		
		# 末尾から取り出す.
		var d:ReplayData = redo_list.pop_back()
		var p_vdir = Direction.get_point(d.player_dir)
		var px = d.player_pos.x + p_vdir.x
		var py = d.player_pos.y + p_vdir.y
		player.set_pos(px, py, true)
		player.set_dir(d.player_dir)
		if d.crate_dir != Direction.eType.NONE:
			# 荷物の位置も戻す.
			var xprev = d.crate_pos.x
			var yprev = d.crate_pos.y
			var v = Direction.get_point(d.crate_dir)
			var xnext = xprev + v.x
			var ynext = yprev + v.y
			var crate = Field.search_crate(xprev, yprev)
			crate.set_pos(xnext, ynext, true) # 1つ進める.
		
		# undoに追加 (redoは消さない).
		add_undo(d, false)