【Godot】KinematicBody2Dの is_on_floor() と One wayコリジョンの使い方

この記事では KinemetaicBody2Dの is_on_floor() の使い方と、One way 床 (一方通行床) の使い方を解説します。

KinematicBody2D.is_on_floor() の使い方

KinematicBody2Dについて

KinematicBody2Dとは、物理エンジンで動作するノードでありながら、移動パラメータや移動タイミングをスクリプトで指定可能なオブジェクトなります。

物理エンジンで動作する2Dノードの比較は以下のとおりです。

ノード名	物理エンジンでの制御	用途
RigidBody2D	自動で動く	物理制御のみで動くようなオブジェクト。粒子やバネ、流体など
StaticBody2D	物理制御するが動かさないオブジェクト	床や壁など、衝突したときに動かないが物理制御したいオブジェクト。スクリプトで動かすことも可能なので、移動床なども可能
KinematicBody2D	スクリプトで専用の物理関数を呼び出すことで動く	スクリプトで細かく制御したい物理オブジェクト。プレイヤーキャラや敵キャラなど

RigidBody2D や StaticBody2D は、基本的に物理シミュレーションで動くような Physics puzzle game (物理パズルゲーム) や Sandbox game (サンドボックスゲーム) を作るのに向いています。

このあたりの使い方は以下の記事に書いていますので、興味があれば参考になるかもしれません。

そしてKinematicBody2D の用途としては、主に足場をジャンプで飛び移るアクションゲームの 2D Platformer (プラットフォーマー) や Top-down (トップビュー) のようなゲームと相性が良いです。

move_and_slide() を使って移動処理を行う

KinematicBody2Dノードには、move_and_slide() というとても便利な関数が用意されています。これを使用した最低限の移動とジャンプを実装したコードは以下のとおりです。

extends KinematicBody2D

const MOVE_SPEED = 50
const DECAY_MOVE_SPEED = 0.9 
const GRAVITY = 50
const JUMP_POWER = 1000

var _velocity = Vector2.ZERO # 速度ベクトル

func _physics_process(delta: float) -> void:
    # 重力を加算
    _velocity.y += GRAVITY
    
    # 移動量を減衰.
    _velocity.x *= DECAY_MOVE_SPEED
    
    # 左右移動.
    if Input.is_action_pressed("ui_left"):
        _velocity.x -= MOVE_SPEED # 左方向に移動
    elif Input.is_action_pressed("ui_right"):
        _velocity.x += MOVE_SPEED # 右方向に移動.
    
    # ジャンプ.
    if Input.is_action_just_pressed("ui_accept"):
        # SPACEキーでジャンプする.
        _velocity.y = -JUMP_POWER
    
    # 移動処理を行う
    _velocity = move_and_slide(_velocity)

このように、移動ベクトル _velocity の値を move_and_slide() に渡すことで、衝突応答と移動処理を簡単に実装することができます。

is_on_floor() の使い方

次にジャンプ中かどうかを判定する方法です。KinematicBody2D には is_on_floor() という便利関数が用意されていて、この関数で床の上に乗っているかどうかを簡単に判定できます。

ただ、is_on_floor() を使用するには、move_and_slide() の二番目の引数に床と判定する方向ベクトルを指定する必要があります。

    # ジャンプ.
    if _is_jumping == false:
        # ジャンプ中でなければジャンプできる.
        if Input.is_action_just_pressed("ui_accept"):
            # SPACEキーでジャンプする.
            _velocity.y = -JUMP_POWER
    
    # 移動処理.
    # ※第2引数に床と判定する方向ベクトルを渡す必要がある
    _velocity = move_and_slide(_velocity, Vector2.UP)
    
    if is_on_floor():
        _is_jumping = false # 床に着地している
    else:
        _is_jumping = true # ジャンプ中.

move_and_slide() の二番目の引数に Vector2.UP を渡しています。これにより「上から衝突したら床とする」ということとなり、is_on_floor() が正常に動作するようになります。